Platforms to show: All Mac Windows Linux Cross-Platform
Required plugins for this example: MBS ChartDirector Plugin
You find this example project in your Plugins Download as a Xojo project file within the examples folder: /ChartDirector/fontxy
This example is the version from Sun, 17th Mar 2012.
Project "fontxy.xojo_binary_project"
Class App Inherits Application
Const kEditClear = "&Löschen"
Const kFileQuit = "Beenden"
Const kFileQuitShortcut = ""
End Class
Class PicWindow Inherits Window
EventHandler Sub Open()
// The data for the chart
dim Data0(-1) as double = array(100, 125, 245, 147, 67.0)
dim Data1(-1) as double = array(85, 156, 179, 211, 123.0)
dim Data2(-1) as double = array(97, 87, 56, 267, 157.0)
dim labels(-1) as string = array("Mon Jun 4", "Tue Jun 5", "Wed Jun 6", "Thu Jun 7","Fri Jun 8")
// Create a XYChart object of size 540 x 350 pixels
dim c as new CDXYChartMBS(540, 350)
// Set the plot area to start at (120, 40) and of size 280 x 240 pixels
call c.setPlotArea(120, 40, 280, 240)
// Add a title to the chart using 20 pts Times Bold Italic (timesbi.ttf) font and
// using a deep blue color (&h000080)
call c.addTitle("Weekly Server Load", "timesbi.ttf", 20, &h000080)
// Add a legend box at (420, 100) (right of plot area) using 12 pts Times Bold
// font. Sets the background of the legend box to light grey &hd0d0d0 with a 1
// pixel 3D border.
c.addLegend(420, 100, true, "timesbd.ttf", 12).setBackground(&hd0d0d0, &hd0d0d0, 1)
// Add a title to the y-axis using 12 pts Arial Bold/deep blue (&h000080) font.
// Set the background to yellow (&hffff00) with a 2 pixel 3D border.
c.yAxis.setTitle("Throughput (per hour)", "arialbd.ttf", 12, &h000080).setBackground(&hffff00, &hffff00, 2)
// Use 10 pts Arial Bold/orange (&hcc6600) font for the y axis labels
call c.yAxis.setLabelStyle("arialbd.ttf", 10, &hcc6600)
// Set the axis label format to "nnn MBytes"
c.yAxis.setLabelFormat("{value} MBytes")
// Use 10 pts Arial Bold/green (&h008000) font for the x axis labels. Set the
// label angle to 45 degrees.
c.xAxis.setLabelStyle("arialbd.ttf", 10, &h008000).setFontAngle(45)
// Set the labels on the x axis.
call c.xAxis.setLabels(labels)
// Add a 3D stack bar layer with a 3D depth of 5 pixels
dim layer as CDBarLayerMBS
layer = c.addBarLayer(CDXYChartMBS.kStack, 5)
// Use Arial Italic as the default data label font in the bars
call layer.setDataLabelStyle("ariali.ttf")
// Use 10 pts Times Bold Italic (timesbi.ttf) as the aggregate label font. Set
// the background to flesh (&hffcc66) color with a 1 pixel 3D border.
layer.setAggregateLabelStyle("timesbi.ttf", 10).setBackground(&hffcc66, CDXYChartMBS.kTransparent, 1)
// Add the first data set to the stacked bar layer
call layer.addDataSet(data0, -1, "Server #1")
// Add the second data set to the stacked bar layer
call layer.addDataSet(data1, -1, "Server #2")
// Add the third data set to the stacked bar layer, and set its data label font
// to Arial Bold Italic.
dim TextBox as CDTextBoxMBS
dim dataset as CDDataSetMBS
dataset = layer.addDataSet(data2, -1, "Server #3")
textbox= dataset.setDataLabelStyle( "arialbi.ttf")
// Set the data label font color for the third data set to yellow (&hffff00)
textbox.setFontColor(&hffff00)
// Set the data label background color to the same color as the bar segment, with
// a 1 pixel 3D border.
textbox.setBackground(CDXYChartMBS.kSameAsMainColor, CDXYChartMBS.kTransparent, 1)
// Output the chart
Backdrop=c.makeChartPicture
End EventHandler
End Class
MenuBar MenuBar1
MenuItem FileMenu = "&Ablage"
MenuItem FileQuit = "#App.kFileQuit"
MenuItem EditMenu = "&Bearbeiten"
MenuItem EditUndo = "&Rückgängig"
MenuItem UntitledMenu1 = "-"
MenuItem EditCut = "&Ausschneiden"
MenuItem EditCopy = "&Kopieren"
MenuItem EditPaste = "&Einfügen"
MenuItem EditClear = "#App.kEditClear"
MenuItem UntitledMenu0 = "-"
MenuItem EditSelectAll = "&Alles auswählen"
End MenuBar
End Project
The items on this page are in the following plugins: MBS ChartDirector Plugin.